dlgEvent_record_AfterRow

Function called by dialog code event after the user leaves a row.

Syntax

PUBLIC FUNCTION dlgEvent_record_AfterRow( 
   dlg ui.DIALOG, 
   uiMode SMALLINT,
   dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
  RETURNS (libdbappEvents.DlgCtrlInstruction_Type)
The function parameters are:
  1. dlg. This is a ui.DIALOG object referencing the current dialog. The dialog can implement an INPUT, INPUT ARRAY, DISPLAY ARRAY, MENU, or CONSTRUCT. For more information, see The Dialog class in Genero Business Development Language User Guide.
  2. uiMode. This is an integer value defining the current mode or state in relation to user action in the dialog, form, or application. Modes are defined as constants in the libdbappFormUI file in the libdbapp library.
    Table 1. UI modes
    Description Applies to ... Constant Value
    Display DISPLAY ARRAY C_MODE_DISPLAY 1
    Modify INPUT \ INPUT ARRAY C_MODE_MODIFY 2
    Add INPUT \ INPUT ARRAY C_MODE_ADD 3
    Search CONSTRUCT C_MODE_SEARCH 4
    Empty MENU C_MODE_EMPTY 5
    Exit form The form C_MODE_EXIT_FORM 6
    Exit app The app C_MODE_EXIT_APP 7
    Undefined All (array, form, or app) C_MODE_UNDEFINED 0
  3. dlgCtrlInstruction is a libdbappEvents.DlgCtrlInstruction_Type defining the dialog control instruction. Instructions available in the function are shown in the table.
    Table 2. Dialog control instructions
    Description Constant Value
    Accept dialog ACCEPT_DIALOG 1
    Continue dialog CONTINUE_DIALOG 2
    Exit dialog EXIT_DIALOG 3

The function returns a dialog control instruction value defined by libdbappEvents.DlgCtrlInstruction_Type.

Usage

When you select the After Row property for the creation of the event, a function shell is created. Enter your code in the function.

This function is called when a dialog controlling a DISPLAY ARRAY or INPUT ARRAY loses the focus, or the user moves to another row in the list but before leaving the current row.
Note:

For an INPUT (fields in a GRID container) dialog instance, use the AfterInput function.

In an editable array, use this function to implement row validation and prevent the user from leaving the list or moving to another row if the validation fails.

It can also be used in other situations, for example, when the user deletes a row, or when the user inserts a new row. It is executed after the AFTER FIELD function call.

This function is called before the default validation that the BAM generates for an INSERT, UPDATE, or DELETE. This means it is called before:
  • prompting the user for confirmation with a (Yes/No/Cancel) dialog
  • processing the CRUD operation or in the case of failure displaying the SQL error and continuing the dialog

Example: After Row

This example uses the After Row code event for the Account form in the OfficeStore demo.

In this example the functions checks the state (uiMode) of the dialog. A validation check is then only performed if a row is being inserted (C_MODE_ADD) or updated (C_MODE_MODIFY). The control instruction is set to return a CONTINUE_DIALOG instruction, if the data entered in a field is not valid. 

PUBLIC FUNCTION dlgEvent_recAccount_AfterRow(dlg ui.DIALOG, uiMode SMALLINT,
      dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
    RETURNS (libdbappEvents.DlgCtrlInstruction_Type)

    CALL libdbappCore.log(C_LOG_INFO, SFMT("dlgEvent_recAccount_AfterRow (Row scope) is raised  -  uimode = %1", uiMode))

    IF uiMode == C_MODE_ADD OR uiMode == C_MODE_MODIFY THEN
        IF dlg.getFieldBuffer("recAccount.city") IS NULL 
            AND dlg.getFieldBuffer("recAccount.zip") IS NOT NULL THEN
            ERROR "  IN AFTER ROW You must specify a city because zipcode is not null."
            CALL dlg.nextField("recAccount.city")
            LET dlgCtrlInstruction = libdbappEvents.CONTINUE_DIALOG
        END IF
    ELSE
        -- No validation for other uiMode states
        DISPLAY "No validation for uiMode = ", uiMode
    END IF
    
    CALL libdbappCore.log(C_LOG_INFO, "dlgEvent_recAccount_AfterRow (Row scope) is exited")

    RETURN dlgCtrlInstruction
END FUNCTION

For more information on the libdbappCore.log() function, go to DBAPPDEBUG and the debug level API.