dlgEvent_OnActionCancel

Function called to overwrite a predefined action to cancel the current interactive instruction.

Syntax

PUBLIC FUNCTION dlgEvent_OnActionCancel( 
   dlg ui.DIALOG, 
   uiMode SMALLINT,
   dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
RETURNS (libdbappEvents.DlgCtrlInstruction_Type)
The function parameters are:
  1. dlg. This is a ui.DIALOG object referencing the current dialog. The dialog can implement an INPUT, INPUT ARRAY, DISPLAY ARRAY, MENU, or CONSTRUCT. For more information, see The Dialog class in Genero Business Development Language User Guide.
  2. uiMode. This is an integer value defining the current mode or state in relation to user action in the dialog, form, or application. Modes are defined as constants in the libdbappFormUI file in the libdbapp library.
    Table 1. UI modes
    Description Applies to ... Constant Value
    Display DISPLAY ARRAY C_MODE_DISPLAY 1
    Modify INPUT \ INPUT ARRAY C_MODE_MODIFY 2
    Add INPUT \ INPUT ARRAY C_MODE_ADD 3
    Search CONSTRUCT C_MODE_SEARCH 4
    Empty MENU C_MODE_EMPTY 5
    Exit form The form C_MODE_EXIT_FORM 6
    Exit app The app C_MODE_EXIT_APP 7
    Undefined All (array, form, or app) C_MODE_UNDEFINED 0
  3. dlgCtrlInstruction is a libdbappEvents.DlgCtrlInstruction_Type defining the dialog control instruction.
    Instructions available will vary depending on the uiMode:
    • For display, modify, add, and search mode, see Table 2.
    • For empty mode, see Table 3.
    Table 2. Dialog control instructions for display/modify/add/search modes
    Description Constant Value
    Accept dialog ACCEPT_DIALOG 1
    Continue dialog CONTINUE_DIALOG 2
    Exit dialog EXIT_DIALOG 3
    Table 3. Dialog control instructions for empty mode
    Description Constant Value
    Continue menu CONTINUE_MENU 4
    Exit menu EXIT_DIALOG 5

The function returns a dialog control instruction value defined by libdbappEvents.DlgCtrlInstruction_Type.

Usage

When you select the On Action Cancel property for the creation of the event, a function shell is created. Enter your code in the function.

Use this function to overwrite a predefined action to cancel the current interactive instruction.

Example: On Action Cancel

This example uses the On Action Cancel code event for the Account form in the OfficeStore demo.

In this example, the function returns control to the dialog based on the user selection of yes or no in the mbox_yn dialog.

If the user is not canceling, the status of uiMode is checked. Depending on the current mode (C_MODE_ADD or C_MODE_SEARCH), the function restoreRequiredElementStyle is called to restore original presentation styles to form elements.

The restoreRequiredElementStyle function references two user-defined parameters:
  • m_frmElements stores the name of some elements in the form
  • m_frmElementsStyle stores the original presentation styles of the m_frmElements elements
The parameters hold values set in the dlgEvent_OnOpenForm event.
# AccountForm.4gl

-- import user-defined functions
IMPORT FGL myAccountFunc

# user defined module variables 
DEFINE m_frmElements DYNAMIC ARRAY OF STRING = 
   ["account_userid_label1", "account_lastname_label1", "account_email_label1", "account_state_label1"] 
    -- form elements
DEFINE m_frmElementsStyle DYNAMIC ARRAY OF STRING --Saved styles

# ...

PUBLIC FUNCTION dlgEvent_OnActionCancel(dlg ui.DIALOG, uiMode SMALLINT, 
    dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
    RETURNS (libdbappEvents.DlgCtrlInstruction_Type)

    CALL libdbappCore.log(C_LOG_INFO, "dlgEvent_OnActionCancel (Form scope) is raised")
                   
    IF NOT myAccountFunc.mbox_yn("Accounts", "Are you sure you want to cancel?","question") THEN
        LET dlgCtrlInstruction = CONTINUE_DIALOG 
    ELSE
       IF uiMode == libdbappFormUI.C_MODE_ADD OR uiMode == libdbappFormUI.C_MODE_SEARCH THEN
         CALL myAccountFunc.restoreRequiredElementStyle(dlg, m_frmElements, m_frmElementsStyle)
       END IF
    END IF  
   
    RETURN dlgCtrlInstruction
END FUNCTION

For more information on the libdbappCore.log() function, go to DBAPPDEBUG and the debug level API.

In this section there are examples of the user-defined functions restoreRequiredElementStyle and mbox_yn called in the event function. The function restoreRequiredElementStyle is called to restore the original presentation styles of some form elements.

The restoreRequiredElementStyle function references two parameters:
  • The lbllist array that stores a list of form elements.
  • The lblStylelist array that stores the original presentation styles of lbllist.

The mbox_yn function is used to confirm the user action to cancel in the event function.

All functions that you would reuse across forms and applications would reside in a module you create. To use these functions in your project, you would import your module into the entity module (for example, AccountForm.4gl) using the IMPORT FGL statement.
# MyAccountFunc.4gl

FUNCTION restoreRequiredElementStyle(dlg ui.Dialog, lbllist DYNAMIC ARRAY OF STRING, 
                                      lblStylelist DYNAMIC ARRAY OF STRING)
    DEFINE i INTEGER

    FOR i = 1 TO lbllist.getLength()
        CALL dlg.getForm().setElementStyle(lbllist[i], lblStylelist[i])
    END FOR
END FUNCTION
# MyAccountFunc.4gl

FUNCTION mbox_yn(t STRING, m STRING, i STRING)
    DEFINE r INTEGER
    MENU t ATTRIBUTES(STYLE="dialog",COMMENT=m,IMAGE=i)
      COMMAND "Yes"  LET r = TRUE EXIT MENU
      COMMAND "No"   LET r = FALSE EXIT MENU
    END MENU
    RETURN r
END FUNCTION