dlgEvent_OnActionStatesChange

Function called to make action state change at the form level.

Syntax

PUBLIC FUNCTION dlgEvent_OnActionStatesChange( 
   dlg ui.DIALOG, 
   uiMode SMALLINT )

The function parameters are:

dlg. This is a ui.DIALOG object referencing the current dialog. The dialog can implement an INPUT, INPUT ARRAY, DISPLAY ARRAY, MENU, or CONSTRUCT. For more information, see The Dialog class in Genero Business Development Language User Guide.

uiMode. This is an integer value defining the current mode or state in relation to user action in the dialog, form, or application. Modes are defined as constants in the libdbappFormUI file in the libdbapp library.

Table 1. UI modes
Description	Applies to ...	Constant	Value
Display	`DISPLAY ARRAY`	C_MODE_DISPLAY	1
Modify	`INPUT \ INPUT ARRAY`	C_MODE_MODIFY	2
Add	`INPUT \ INPUT ARRAY`	C_MODE_ADD	3
Search	`CONSTRUCT`	C_MODE_SEARCH	4
Empty	`MENU`	C_MODE_EMPTY	5
Exit form	The form	C_MODE_EXIT_FORM	6
Exit app	The app	C_MODE_EXIT_APP	7
Undefined	All (array, form, or app)	C_MODE_UNDEFINED	0

Usage

When you select the On Action States Update (Form) property for the creation of the event, a function shell is created. Enter your code in the function.

Use this function to set the action state for default actions and defined actions. Use the uiMode parameter in an IF or CASE statement to set the state of an action based on the mode of the current dialog.

Example: form On Action States Change

This example uses the On Action States Update (Form) code event for a form in the OfficeStore demo.

In this example, the function disables some actions on mobile UIs. If the UI is not mobile, it enables or disables the actions depending on the state of uiMode.

A user-defined variable actionList is defined to store the name of some actions, and this variable is referenced by the user-defined function setActionStatesForUImode called to set the action states.

# <entity>.4gl

-- import user-defined functions
IMPORT FGL myAccountFunc 

PUBLIC FUNCTION dlgEvent_OnActionStatesChange(dlg ui.DIALOG, uiMode SMALLINT)

    DEFINE actionList DYNAMIC ARRAY OF STRING = ["reportprint", "print_list"] 
    -- Form actions
    DEFINE i INTEGER

    DISPLAY "dlgEvent_OnActionStatesChange (Form scope) is raised"
    DISPLAY "uiMode: ", uiMode
    IF libdbapp_isMobile() THEN
        FOR i = 1 TO actionList.getLength()
            CALL dlg.setActionActive(actionList[i], FALSE)
            CALL dlg.setActionHidden(actionList[i], TRUE)
        END FOR
    ELSE
       CALL myAccountFunc.setActionStatesForUImode(dlg, actionList, uiMode)
    END IF

    DISPLAY "dlgEvent_OnActionStatesChange (Form scope) is exited"
END FUNCTION

setActionStatesForUImode

In this section there is an example of the user-defined function setActionStatesForUImode called in the event function.

This function enables or disables the actions in the actionList depending on the state of uiMode.

All functions that you would reuse across forms and applications would reside in a module you create. To use these functions in your project, you would import your module into the entity module (for example, AccountForm.4gl) using the IMPORT FGL statement.

# MyAccountFunc.4gl

FUNCTION setActionStatesForUImode(dlg ui.Dialog, actionList DYNAMIC ARRAY OF STRING, 
                                  uiMode SMALLINT)
   DEFINE i INTEGER
     CASE uiMode
       WHEN C_MODE_DISPLAY
          FOR i = 1 TO actionList.getLength()
            CALL dlg.setActionActive(actionList[i], TRUE)
            CALL dlg.setActionHidden(actionList[i], FALSE)
          END FOR
       WHEN C_MODE_MODIFY
         FOR i = 1 TO actionList.getLength()
            CALL dlg.setActionActive(actionList[i], FALSE)
            CALL dlg.setActionHidden(actionList[i], TRUE)
         END FOR
       WHEN C_MODE_ADD
         FOR i = 1 TO actionList.getLength()
            CALL dlg.setActionActive(actionList[i], FALSE)
            CALL dlg.setActionHidden(actionList[i], TRUE)
         END FOR
       WHEN C_MODE_SEARCH
                -- [...]
       WHEN C_MODE_EMPTY
         FOR i = 1 TO actionList.getLength()
            CALL dlg.setActionActive(actionList[i], FALSE)
            CALL dlg.setActionHidden(actionList[i], TRUE)
         END FOR
       OTHERWISE
         DISPLAY "unknown mode  ", uiMode
     END CASE
END FUNCTION