dlgEvent_OnActionClose

Function called to overwrite a predefined action to close the current interactive instruction.

Syntax

PUBLIC FUNCTION dlgEvent_OnActionClose( 
   dlg ui.DIALOG, 
   uiMode SMALLINT,
   dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
RETURNS (libdbappEvents.DlgCtrlInstruction_Type)
The function parameters are:
  1. dlg. This is a ui.DIALOG object referencing the current dialog. The dialog can implement an INPUT, INPUT ARRAY, DISPLAY ARRAY, MENU, or CONSTRUCT. For more information, see The Dialog class in Genero Business Development Language User Guide.
  2. uiMode. This is an integer value defining the current mode or state in relation to user action in the dialog, form, or application. Modes are defined as constants in the libdbappFormUI file in the libdbapp library.
    Table 1. UI modes
    Description Applies to ... Constant Value
    Display DISPLAY ARRAY C_MODE_DISPLAY 1
    Modify INPUT \ INPUT ARRAY C_MODE_MODIFY 2
    Add INPUT \ INPUT ARRAY C_MODE_ADD 3
    Search CONSTRUCT C_MODE_SEARCH 4
    Empty MENU C_MODE_EMPTY 5
    Exit form The form C_MODE_EXIT_FORM 6
    Exit app The app C_MODE_EXIT_APP 7
    Undefined All (array, form, or app) C_MODE_UNDEFINED 0
  3. dlgCtrlInstruction is a libdbappEvents.DlgCtrlInstruction_Type defining the dialog control instruction.
    Instructions available will vary depending on the uiMode:
    • For display, modify, and add mode, see Table 2.
    • For empty mode, see Table 3.
    Table 2. Dialog control instructions for display/modify/add/search modes
    Description Constant Value
    Accept dialog ACCEPT_DIALOG 1
    Continue dialog CONTINUE_DIALOG 2
    Exit dialog EXIT_DIALOG 3
    Table 3. Dialog control instructions for empty mode
    Description Constant Value
    Continue menu CONTINUE_MENU 4
    Exit menu EXIT_DIALOG 5

The function returns a dialog control instruction value defined by libdbappEvents.DlgCtrlInstruction_Type.

Usage

When you select the On Action Close property for the creation of the event, a function shell is created. Enter your code in the function.

Use this function to overwrite a predefined action to close the current interactive instruction.

Example: On Action Close

This example uses the On Action Close code event for a form in the OfficeStore demo.

In this example, if no field in the dialog has changed, the user is prompted to confirm the close action. This example uses a user-defined function, mbox_yn, to verify the action. 

# <entity>.4gl

-- import user-defined functions
IMPORT FGL myAccountFunc

PUBLIC FUNCTION dlgEvent_OnActionClose(dlg ui.DIALOG, uiMode SMALLINT,
      dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
    RETURNS (libdbappEvents.DlgCtrlInstruction_Type)

    DISPLAY "dlgEvent_OnActionClose (Form scope) is raised"
    
    IF NOT dlg.getFieldTouched("*") THEN
       IF NOT myAccountFunc.mbox_yn("Accounts", "Are you sure you want to close?", "question") THEN
         LET dlgCtrlInstruction = CONTINUE_DIALOG
       END IF
    END IF

    RETURN dlgCtrlInstruction
END FUNCTION

mbox_yn

In this section there is an example of the mbox_yn function that implements a message box in the event function to confirm the user action.

All functions that you would reuse across forms and applications would reside in a module you create. To use these functions in your project, you would import your module into the entity module (for example, AccountForm.4gl) using the IMPORT FGL statement.
# MyAccountFunc.4gl

FUNCTION mbox_yn(t STRING, m STRING, i STRING)
    DEFINE r INTEGER
    MENU t ATTRIBUTES(STYLE="dialog",COMMENT=m,IMAGE=i)
      COMMAND "Yes"  LET r = TRUE EXIT MENU
      COMMAND "No"   LET r = FALSE EXIT MENU
    END MENU
    RETURN r
END FUNCTION