dlgEvent_OnActionNew

Function called to overwrite a predefined action to insert a new row in the current dialog.

Syntax

PUBLIC FUNCTION dlgEvent_OnActionNew( 
   dlg ui.DIALOG, 
   uiMode SMALLINT,
   dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
RETURNS (libdbappEvents.DlgCtrlInstruction_Type)
The function parameters are:
  1. dlg. This is a ui.DIALOG object referencing the current dialog. The dialog can implement an INPUT, INPUT ARRAY, DISPLAY ARRAY, MENU, or CONSTRUCT. For more information, see The Dialog class in Genero Business Development Language User Guide.
  2. uiMode. This is an integer value defining the current mode or state in relation to user action in the dialog, form, or application. Modes are defined as constants in the libdbappFormUI file in the libdbapp library.
    Table 1. UI modes
    Description Applies to ... Constant Value
    Display DISPLAY ARRAY C_MODE_DISPLAY 1
    Modify INPUT \ INPUT ARRAY C_MODE_MODIFY 2
    Add INPUT \ INPUT ARRAY C_MODE_ADD 3
    Search CONSTRUCT C_MODE_SEARCH 4
    Empty MENU C_MODE_EMPTY 5
    Exit form The form C_MODE_EXIT_FORM 6
    Exit app The app C_MODE_EXIT_APP 7
    Undefined All (array, form, or app) C_MODE_UNDEFINED 0
  3. dlgCtrlInstruction is a libdbappEvents.DlgCtrlInstruction_Type defining the dialog control instruction.
    Instructions available will vary depending on the uiMode:
    • For display, modify, add, and search mode, see Table 2.
    • For empty mode, see Table 3.
    Table 2. Dialog control instructions for display/modify/add/search modes
    Description Constant Value
    Accept dialog ACCEPT_DIALOG 1
    Continue dialog CONTINUE_DIALOG 2
    Exit dialog EXIT_DIALOG 3
    Table 3. Dialog control instructions for empty mode
    Description Constant Value
    Continue menu CONTINUE_MENU 4
    Exit menu EXIT_DIALOG 5

The function returns a dialog control instruction value defined by libdbappEvents.DlgCtrlInstruction_Type.

Usage

When you select the On Action New property for the creation of the event, a function shell is created. Enter your code in the function.

Use this function to overwrite a predefined action to insert a new row in the current dialog.

Example: On Action New

This example uses the On Action New code event for the Account form in the OfficeStore demo.

In this example the user-defined function setRequiredElementStyle is called to change the presentation styles of form elements for which the user must enter values.

The setRequiredElementStyle function references the user-defined parameter m_frmElements, which stores the name of some elements in the form. The parameter is defined as a module variable in the AccountForm.4gl file.

The call to the function changes the presentation style of m_frmElements to a style you have defined in the styles file (dbapp.4st). For more information on working with custom presentation styles in your BAM project, see the Modify styles page. 

# AccountForm.4gl

# user defined module variables 
DEFINE m_frmElements DYNAMIC ARRAY OF STRING = 
   ["account_userid_label1", "account_lastname_label1", "account_email_label1", "account_state_label1"] -- form elements
DEFINE m_frmElementsStyle DYNAMIC ARRAY OF STRING --Saved styles

# ...

PUBLIC FUNCTION dlgEvent_OnActionNew(dlg ui.DIALOG, uiMode SMALLINT,
      dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type)
    RETURNS (libdbappEvents.DlgCtrlInstruction_Type)

    DISPLAY "dlgEvent_OnActionNew (Form scope) is raised"
  
    CALL myAccountFunc.setRequiredElementStyle(dlg, m_frmElements)

    RETURN dlgCtrlInstruction
END FUNCTION
In this section there is an example of the setRequiredElementStyle function called in the event function. All functions that you would reuse across forms and applications would reside in a module you create. To use these functions in your project, you would import your module into the entity module (for example, AccountForm.4gl) using the IMPORT FGL statement.
FUNCTION setRequiredElementStyle(dlg, lbllist)
    DEFINE lbllist DYNAMIC ARRAY OF STRING
    DEFINE dlg ui.Dialog
    DEFINE i INTEGER

    FOR i = 1 TO lbllist.getLength()
        CALL dlg.getForm().setElementStyle(lbllist[i], "elementRequired")
    END FOR
END FUNCTION