dlgEvent_record_BeforeField

Function called before user enters a record field.

Syntax

PUBLIC FUNCTION dlgEvent_record_BeforeField( 
   dlg ui.DIALOG, 
   uiMode SMALLINT,
   dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type,
   currentField STRING )
  RETURNS (libdbappEvents.DlgCtrlInstruction_Type)

The function parameters are:

  1. dlg. This is a ui.DIALOG object referencing the current dialog. The dialog can implement an INPUT, INPUT ARRAY, DISPLAY ARRAY, MENU, or CONSTRUCT. For more information, see The Dialog class in Genero Business Development Language User Guide.
  2. uiMode. This is an integer value defining the current mode or state in relation to user action in the dialog, form, or application. Modes are defined as constants in the libdbappFormUI file in the libdbapp library.
    Table 1. UI modes
    Description Applies to ... Constant Value
    Display DISPLAY ARRAY C_MODE_DISPLAY 1
    Modify INPUT \ INPUT ARRAY C_MODE_MODIFY 2
    Add INPUT \ INPUT ARRAY C_MODE_ADD 3
    Search CONSTRUCT C_MODE_SEARCH 4
    Empty MENU C_MODE_EMPTY 5
    Exit form The form C_MODE_EXIT_FORM 6
    Exit app The app C_MODE_EXIT_APP 7
    Undefined All (array, form, or app) C_MODE_UNDEFINED 0
  3. dlgCtrlInstruction is a libdbappEvents.DlgCtrlInstruction_Type defining the DIALOG control instruction. Instructions available in the function are shown in the table.
    Table 2. Dialog control instructions
    Description Constant Value
    Accept dialog ACCEPT_DIALOG 1
    Continue dialog CONTINUE_DIALOG 2
    Exit dialog EXIT_DIALOG 3
    Exit menu EXIT_MENU 4
  4. currentField is a string containing the name of the form field that has the focus.

Returns a dialog instruction value defined by the libdbappEvents.DlgCtrlInstruction_Type type.

Usage

When you select the Before Field property for the creation of the event, a function shell is created. Enter your code in the function.

This function is called in an INPUT, INPUT ARRAY, or CONSTRUCT dialog. Use this function to initialize field values, or to display a message to the user before they move to the field for input or query.

Note: This function can be called only on record fields where:
  • the source field has an outgoing relation to a zoom form.
  • the field has a descending or ascending lookup.

Example: Before Field

This example uses the Before Field code event for a record field in the Account form of the OfficeStore demo.

In this example the value for the "account.country" field is set with the default country code when the uiMode state is input or search. As a result the value is displayed on entry to the field. When the user is modifying the field, a message is returned.

PUBLIC FUNCTION dlgEvent_record1_BeforeField(dlg ui.DIALOG, uiMode SMALLINT, 
                dlgCtrlInstruction libdbappEvents.DlgCtrlInstruction_Type, 
                currentField STRING)
    RETURNS (libdbappEvents.DlgCtrlInstruction_Type)

    DISPLAY "dlgEvent_record1_BeforeField (Field scope) is raised"
    DISPLAY "current field: ", currentfield
    CASE currentField
      WHEN "account.country"
         CASE 
            WHEN (uiMode=C_MODE_ADD OR uiMode=C_MODE_SEARCH)
               # set default country
               CALL dlg.setFieldValue(currentfield,"FRA")
            WHEN uiMode=C_MODE_MODIFY
               MESSAGE " Select a country from the list "
         END CASE   
      WHEN "category.catname"
         MESSAGE " Select a category from the list "
      OTHERWISE
        -- ...
    END CASE
    DISPLAY "dlgEvent_record1_BeforeField (Field scope) is exited"

    RETURN dlgCtrlInstruction
END FUNCTION