Example: custlistinp.4gl (Function custarr_input)

The custarr_input function in custlistinp.4gl:

  1 PRIVATE FUNCTION custarr_input() RETURNS ()
  2   DEFINE x INTEGER
  3   DEFINE op CHAR(1)
  4 
  5   LET int_flag = FALSE
  6 
  7   INPUT ARRAY custarr FROM sa_cust.*
  8           ATTRIBUTES(UNBUFFERED,
  9                      CANCEL = FALSE,
 10                      WITHOUT DEFAULTS)
 11 
 12      BEFORE DELETE
 13         DISPLAY "BEFORE DELETE: op=",op
 14         IF op == "N" THEN
 15            LET x = arr_curr()
 16            IF NOT comutils.mbox_yn("Customers",
 17                 "Are you sure you want to delete this record?")
 18            THEN
 19               CANCEL DELETE
 20            END IF
 21            TRY
 22               DELETE FROM customer
 23                   WHERE cust_num = custarr[x].cust_num
 24            CATCH
 25               ERROR SQLERRMESSAGE
 26               CANCEL DELETE
 27            END TRY
 28         END IF
 29 
 30      AFTER DELETE
 31         DISPLAY "AFTER DELETE: op=",op
 32         IF op == "N" THEN
 33            MESSAGE "Record has been deleted successfully"
 34         ELSE
 35            LET op = "N"
 36         END IF
 37 
 38      AFTER FIELD cust_name
 39         DISPLAY "AFTER FIELD cust_name: op=",op
 40         LET x = arr_curr()
 41         IF custarr[x].cust_name MATCHES "*@#$%^&()*" THEN
 42            ERROR "This field contains invalid characters"
 43            NEXT FIELD CURRENT
 44         END IF
 45 
 46      ON ROW CHANGE
 47         DISPLAY "ON ROW CHANGE: op=",op
 48         IF op != "I" THEN LET op = "M" END IF
 49 
 50      BEFORE INSERT
 51         DISPLAY "BEFORE INSERT: op=",op
 52         LET op = "T"
 53         LET x = arr_curr()
 54         LET custarr[x].cust_num = 1000 + arr_curr()
 55         LET custarr[x].cust_name = "<undefined>"
 56 
 57      AFTER INSERT
 58         DISPLAY "AFTER INSERT: op=",op
 59         LET op = "I"
 60 
 61      BEFORE ROW
 62         DISPLAY "BEFORE ROW: op=",op
 63         LET op = "N"
 64 
 65      AFTER ROW
 66         DISPLAY "AFTER ROW: op=",op
 67         IF int_flag THEN EXIT INPUT END IF
 68         LET x = arr_curr()
 69         IF op == "M" OR op == "I" THEN
 70            IF custarr[x].cust_name MATCHES "[0-9]*" THEN
 71               ERROR "Customer name seems invalid"
 72               NEXT FIELD cust_name
 73            END IF
 74         END IF
 75         IF op == "I" THEN
 76            TRY
 77               INSERT INTO customer VALUES ( custarr[x].* )
 78               MESSAGE "Record has been inserted successfully"
 79            CATCH
 80               ERROR SQLERRMESSAGE
 81               NEXT FIELD CURRENT
 82            END TRY
 83         END IF
 84         IF op == "M" THEN
 85            TRY
 86               LET x = arr_curr()
 87               UPDATE customer SET customer.* = custarr[x].*
 88                   WHERE cust_num = custarr[x].cust_num
 89               MESSAGE "Record has been updated successfully"
 90            CATCH
 91               ERROR "Could not update the record in database!"
 92               NEXT FIELD CURRENT
 93            END TRY
 94         END IF
 95 
 96   END INPUT
 97 
 98 END FUNCTION