Attributes on array definitions

In type specifications, the attributes-list clause is:

{ ATTRIBUTE | ATTRIBUTES } ( attribute [ = "value" ] [,...] )

1. attribute is the name of a definition attribute.
2. value is the value for the definition attribute, it is optional for boolean attributes.

In the next code example, the array type definition gets definition attributes, to specify the corresponding field names for JSON serialization:

IMPORT util
  
TYPE t_items DYNAMIC ARRAY ATTRIBUTES(json_name="items") OF
     RECORD
         item_num INTEGER ATTRIBUTES(json_name="id"),
         item_desc VARCHAR(50)
     END RECORD

DEFINE stock RECORD
         itemlist t_items
     END RECORD

MAIN

    LET stock.itemlist[1].item_num = 998
    LET stock.itemlist[1].item_desc = "Hand gloves"
    LET stock.itemlist[2].item_num = 999
    LET stock.itemlist[2].item_desc = "Blue hat"

    DISPLAY util.JSON.format(util.JSON.stringify(stock))

END MAIN

Output:

{
    "items": [
        {
            "id": 998,
            "item_desc": "Hand gloves"
        },
        {
            "id": 999,
            "item_desc": "Blue hat"
        }
    ]
}